Ejemplo Temp()

' gambas class file

'by postapase
'http://novatocodegambas.blogspot.com.uy/

Public ArchivoTemporal As File
Public RutaArchivo As String = User.home
Public RutaArchivoTemporal As String
Public Contador As Integer


Public Sub Form_Open()

RutaArchivoTemporal = Temp()
LabRutaTemporal.Text = RutaArchivoTemporal
TextArea1.Clear()
btnGuardarArchivo.Enabled = False

End

Public Sub btnAgregarTexto_Click()

ArchivoTemporal = Open RutaArchivoTemporal For Write Append

Write #ArchivoTemporal, TextBox1.Text & gb.NewLine

Close #ArchivoTemporal

LeerDatosArchivoTemporal()

btnGuardarArchivo.Enabled = True

TextBox1.Clear()
TextBox1.SetFocus()

End

Public Sub LeerDatosArchivoTemporal()
Dim LineaX As String

TextArea1.Clear()

ArchivoTemporal = Open RutaArchivoTemporal For Read

While Not Eof(ArchivoTemporal)
Line Input #ArchivoTemporal, LineaX
TextArea1.Text = LineaX & gb.NewLine & TextArea1.Text
Wend

Close ArchivoTemporal

End

Public Sub Button1_Click()

Form_Open()

End

Public Sub btnGuardarArchivo_Click()

Inc Contador

If Exist(RutaArchivo &/ "EjemploTemp-" & Contador) Then btnGuardarArchivo_Click()

Copy RutaArchivoTemporal To RutaArchivo &/ "EjemploTemp-" & Contador

End

Código fuente: Ejemplo-Temp-0.0.1.tar.gz

Escritura directa en un archivo

Buenas, puede suceder que necesitemos un archivo donde guardemos datos para el funcionamiento de nuestro programa sin la intervención del usuario. Aquí les dejo un ejemplo super simple como me gusta a mi para que sea mas fácil comprender.

' gambas class file

' by postapase
' Escritura directa en un archivo

Public Sub Form_Open()
Dim Ruta As String = User.Home & "/prueba.txt" 'Variable de tipo cadena,
' que contiene la ruta donde se guardara/creara el archivo con los datos

Dim Archivo As File 'declaracion de variable de tipo archivo

Me.Center 'Centra el formulario

Archivo = Open Ruta For Create 'Abre archivo, sino existe lo crea

Print #Archivo, "Hola, hoy es el día " & Format(Date, gb.LongDate) 'escribe 1ª linea
Print #Archivo 'deja la linea en blanco, escribe 2ª linea
Print #Archivo, "El archivo se guardo en:" ' escribe 3ª linea
Print #Archivo, Ruta 'escribe 4ª linea

Close #Archivo 'cierra el archivo

End

' Ahora busquen el archivo en User.Home &"/prueba.txt" para ver los resultados

Guardar/Cargar configuraciones en un txt

El Tanteador de tenis de mesa tiene una ventana donde se puede configurar los distintos colores del la interfaz clásica, y también se puede guardar y cargar configuraciones, pero... no esta bien programado ni es cómodo para el usuario.
Por ese motivo me puse a buscar un método mas conveniente para crear archivos de configuraciones de colores que se les puede poner el nombre de la persona que eligió esos colores con lo cual es fácil de identificar cuales son los colores que cada persona eligió, con una extencion a nuestro gusto en este caso yo le asigne la extencion .ConfigColor pero puede ser cualquiera a su elección

 Así se ve el archivo de configuración de colores con dos valores: Letra y Fondo,
pero puede tener cientos de valores según la necesidad de nuestro programa.

' gambas class file

' by postapase
Public JuegoColores As String
Public Fondo As String
Public Letra As String

Public Sub Form_Open()
Me.Center
Me.Caption = "Configuracion de colores"
End

Public Sub btnGuardar_Click()
Dim sPath As String

If Dialog.SaveFile() Then Return
sPath = Dialog.Path
File.Save(sPath & ".ConfigColor", JuegoColores)

End

Public Sub ColorButton1_Change()
Actualizar
End

Public Sub ColorButton2_Change()
Actualizar
End

Public Sub Actualizar()
Letra = "Letra=" & ColorButton1.Value
Fondo = "Fondo=" & ColorButton2.Value
LabPostapase.Foreground = ColorButton1.Value
LabPostapase.Background = ColorButton2.Value
JuegoColores = Letra & gb.NewLine
JuegoColores &= Fondo
End

Public Sub btnCargar_Click()
Dim sPath As String
Dim dato As String
Dim ArchivoX As File
Dim LineaX As String
Dim DatoX As String[]

Dialog.Filter = ["*.ConfigColor", ("Configuración de colores")]

If Dialog.OpenFile() Then Return
sPath = Dialog.Path

ArchivoX = Open sPath For Read

While Not Eof(ArchivoX)

Line Input #ArchivoX, LineaX

If InStr(LineaX, "Letra") <> 0 Then
DatoX = Split(LineaX, "=")
ColorButton1.Value = Val(Trim(DatoX[1]))
Continue
Endif

If InStr(LineaX, "Fondo") <> 0 Then
DatoX = Split(LineaX, "=")
ColorButton2.Value = Val(Trim(DatoX[1]))
Continue
Endif

Wend

Close ArchivoX
Actualizar()

End

Public Sub btnPredeterminados_Click()
ColorButton1.Value = &H000000
ColorButton2.Value = &HFFFFFF
Actualizar()
End

Código fuente:  ConfigColor-0.0.1.tar.gz

Ejemplo de uso de Append

' lo que hace Append es escribir a partir del final del archivo
'si usaramos solo write el archivo se reescribe de cero con la informacion nueva...

' gambas class file

'by postapase
' usando Append
Private RutaX As String = User.Home &/ "Registro_eventos.txt"

Public Sub Form_Open()
Me.Center
TextArea1.Clear
End

Public Sub btnDos_Click()
TextArea1.Clear
AddLog("btnDos_Click")
End

Public Sub btnUno_Click()
TextArea1.Clear
AddLog("btnUno_Click")
TextArea1.Pos = 0
End

Public Sub AddLog(nombre As String)
Dim ArchivoX As File
Dim LineaX As String

ArchivoX = Open RutaX For Write Append ' lo que hace Append es escribir a partir del final del archivo
'si usaramos solo write el archivo se reescribe de cero con la informacion nueva, es decir si guardamos en el
'archivo la palabra "gambas" y despues guardamos otra palabra "libre" el archivo solo contendra la palabra libre
'ahora si usamos el conjunto de comando Write Append veremos gambas en la primera linea y libre en la segunda
'y asi sucesivamente con lo que guardemos en el archivo, aparentemente si el archivo no existe Append lo crea
'Append es ideal para hacer archivos de log por eso hice este ejemplo para que podamos entender
'para que sirve Append y la diferencia con el comando Write si va solo.

Write #ArchivoX, nombre & " - " & Date(Year(Now), Month(Now), Day(Now), Hour(Now), Minute(Now), Second(Now)) & gb.NewLine

Close ArchivoX

LeerArchivo()

End

Public Sub LeerArchivo()
Dim ArchivoX As File
Dim LineaX As String

ArchivoX = Open RutaX For Read

While Not Eof(ArchivoX)
Line Input #ArchivoX, LineaX
TextArea1.Text = LineaX & gb.NewLine & TextArea1.Text
Wend

Close ArchivoX

End

Public Sub btnClear_Click()

If Not Exist(RutaX) Then
Message.Info("Archivo no existe!")
Else
Try Kill RutaX
TextArea1.Clear
Endif

End

Código fuente: append-0.0.1.tar.gz