Paint Clip

Algo que se esta poniendo de moda son las imágenes recortadas en forma de círculo. Bueno aquí les dejo un código algo crudo para que practiquen.

El ejemplo esta en la granja de gambas.

Ejemplo de DFree

En mi programa Taller2015 uso un pendrive viejo de 512 megas jajaja, si si es reviejo pero lo uso para los respaldos automáticos del programa y me di cuenta de que era necesario saber cuanto espacio libre quedaba.
Y buscando en gambas encontré el comando DFree perteneciente al grupo Funciones para Archivos y Carpetas , aquí les dejo un ejemplo muy parecido de como lo utilice.

' gambas class file

'Usando DFree by postapase

Public Sub Form_Open()

Me.Title = Application.Name
TextBox1.Text = User.Home
EspacioDisponible(User.Home)

End

Public Sub Button1_Click()

Dialog.Path = User.Home 'Asigna la ruta predeterminada de dialog cuando se abre)

If Dialog.SelectDirectory() Then Return ' si no se selecciona un directorio dialog devuelve true y retorna
' no haciendo nada y no ejecutando las lineas siguientes. (

TextBox1.Text = Dialog.Path 'pega la ruta elegida en textbox1

EspacioDisponible(Dialog.Path) ' llama a la subrutina EspacioDisponible

End


Public Sub EspacioDisponible(dir As String)

TextLabel1.Text = "Espacio disponible: <b>" & Format$(CString(Dfree(dir) / 1000000), "#.#") & " MB</b>"

'dfree retorna un integer en bytes y para saber los MegaBytes dividimos en 1000000
'cstring convierte el intenger en string para poder concatenarlo con el texto y no de error
'format$ le damos un forma de visualizar el resultado a nuestro gusto en este caso yo elegi "#.#"
'que mostrara todos los numeros a la izquierda y solo una cifra a la derecha

End

Descargar código fuente:
https://www.dropbox.com/s/duqudql1xh6da8m/Usando-DFree-0.0.1.tar.gz?dl=0

Asi se ve en el programa Taller2015

Guardar/Cargar configuraciones en un txt

El Tanteador de tenis de mesa tiene una ventana donde se puede configurar los distintos colores del la interfaz clásica, y también se puede guardar y cargar configuraciones, pero... no esta bien programado ni es cómodo para el usuario.
Por ese motivo me puse a buscar un método mas conveniente para crear archivos de configuraciones de colores que se les puede poner el nombre de la persona que eligió esos colores con lo cual es fácil de identificar cuales son los colores que cada persona eligió, con una extencion a nuestro gusto en este caso yo le asigne la extencion .ConfigColor pero puede ser cualquiera a su elección

 Así se ve el archivo de configuración de colores con dos valores: Letra y Fondo,
pero puede tener cientos de valores según la necesidad de nuestro programa.

' gambas class file

' by postapase
Public JuegoColores As String
Public Fondo As String
Public Letra As String

Public Sub Form_Open()
Me.Center
Me.Caption = "Configuracion de colores"
End

Public Sub btnGuardar_Click()
Dim sPath As String

If Dialog.SaveFile() Then Return
sPath = Dialog.Path
File.Save(sPath & ".ConfigColor", JuegoColores)

End

Public Sub ColorButton1_Change()
Actualizar
End

Public Sub ColorButton2_Change()
Actualizar
End

Public Sub Actualizar()
Letra = "Letra=" & ColorButton1.Value
Fondo = "Fondo=" & ColorButton2.Value
LabPostapase.Foreground = ColorButton1.Value
LabPostapase.Background = ColorButton2.Value
JuegoColores = Letra & gb.NewLine
JuegoColores &= Fondo
End

Public Sub btnCargar_Click()
Dim sPath As String
Dim dato As String
Dim ArchivoX As File
Dim LineaX As String
Dim DatoX As String[]

Dialog.Filter = ["*.ConfigColor", ("Configuración de colores")]

If Dialog.OpenFile() Then Return
sPath = Dialog.Path

ArchivoX = Open sPath For Read

While Not Eof(ArchivoX)

Line Input #ArchivoX, LineaX

If InStr(LineaX, "Letra") <> 0 Then
DatoX = Split(LineaX, "=")
ColorButton1.Value = Val(Trim(DatoX[1]))
Continue
Endif

If InStr(LineaX, "Fondo") <> 0 Then
DatoX = Split(LineaX, "=")
ColorButton2.Value = Val(Trim(DatoX[1]))
Continue
Endif

Wend

Close ArchivoX
Actualizar()

End

Public Sub btnPredeterminados_Click()
ColorButton1.Value = &H000000
ColorButton2.Value = &HFFFFFF
Actualizar()
End

Código fuente:  ConfigColor-0.0.1.tar.gz